Making haxelib api calls

ianharrigan · July 7, 2021, 4:26pm

Howdy all,

Does anyone know how you can make remoting calls to haxelib (http://lib.haxe.org:80/api/3.0/index.n) without having to use neko / haxelib client? Ive tried things like:

        var cnx = haxe.remoting.HttpAsyncConnection.urlConnect("http://lib.haxe.org:80/api/3.0");
        cnx.call(["search", "haxeui-core"], function(d) {
            trace(d);
        });

And just get a “moved permanently” error - is there any documentation anywhere of a way to acheive this sort of stuff? Reading the haxelib source is making my eyes bleed

Cheers,
Ian

ibilon · July 7, 2021, 5:38pm

The moved permanently redirects to http://lib.haxe.org/api/3.0/ which gives me a result, though it still errors.

Having a file with (haxelib/SiteApi.hx at development · HaxeFoundation/haxelib · GitHub)

interface HaxelibApi {
	public function search(word:String):List<{id:Int, name:String}>;
}

and

class SiteProxy extends haxe.remoting.Proxy<HaxelibApi> {}

function main() {
	final site = new SiteProxy(haxe.remoting.HttpConnection.urlConnect("http://lib.haxe.org:80/api/3.0").resolve("api"));
	trace(site.search("haxeui-core"));
}

worked.

Good luck reading the haxelib source, you’ll need it

ianharrigan · July 7, 2021, 5:54pm

Thanks! Im getting this now though:

SiteProxy.hx:3: characters 0-58 : Could not load proxy module HaxelibApi (try using absolute path)

EDIT: any chance you could zip and post your entire project?

ibilon · July 7, 2021, 7:01pm

Had that error too, I think it ignores imports. Also had an error when trying to have it in the same file, so had to put it in another.

Here’s a full project: GitHub - ibilon/haxelibApi

ianharrigan · July 7, 2021, 7:48pm

Nice one, thanks Valentin

ianharrigan · July 8, 2021, 7:30am

It compiles now, but throws this at runtime:

Uncaught TypeError: Cannot read property 'substr' of null
    at Function.HxOverrides.substr
    at haxe_remoting_HttpConnection.call

This is under js

EDIT: so i think the issue is that its trying to use a sync http, and under nodejs that isnt a thing (or doesnt seem to be looking at the code):

		#if (js && !nodejs)
			h.async = false;
		#end

I tried to use HttpAsyncConnection but dont seem to be getting anywhere

EDIT2: Ok, so i can get it compile by using HttpAsyncConnection and haxe.remoting.AsyncProxy:

class HaxelibApi extends haxe.remoting.AsyncProxy<data.haxelib.SiteApi> {
	public static function connect() {
		return new HaxelibApi(haxe.remoting.HttpAsyncConnection.urlConnect("http://lib.haxe.org/api/3.0/").resolve("api"));
	}
}

And changing the call to something like:

            _api = HaxelibApi.connect();
            _api.search("haxeui-core", function(list:List<{id:Int, name:String}>) {
                trace(list);
            });

however, now i get this at runtime:

haxe_ValueException {message: "Invalid path ''", __previousException: undefined, __nativeException: haxe_ValueException, value: "Invalid path ''"}
message: "Invalid path ''"
value: "Invalid path ''"

FINAL EDIT!!! Ok, so ignore more!

I had edited HttpAsyncConnection yesterday to hardcode things… doh! Works fine now… sorry for the spam!

benmerckx · July 8, 2021, 8:21am

Couple years ago I tried something similar. In case you don’t want to deal with the remoting macros, you can use haxe.Serializer directly and send a request like here:

github.com

benmerckx/tape/blob/master/src/tape/registry/Haxelib.hx?ts=4#L68-L80

    
      
                  var packer = new Serializer();
          		packer.serialize(['api', 'infos']);
          		packer.serialize([name]);
                  var request = new OutgoingRequest(
                      new OutgoingRequestHeader(
                          GET, host, '/api/3.0/index.n?__x=$packer', 
                          [
                              new HeaderField('x-haxe-remoting', '1'), 
                              new HeaderField('connection', 'close'), 
                              new HeaderField('content-length', '0')
                          ]
                      ), Empty.instance
                  );

The reponse starts with ‘hxr’ and the rest can de deserialized:

github.com

benmerckx/tape/blob/master/src/tape/registry/Haxelib.hx?ts=4#L89-L93

    
      
          var buf = bytes.toString();
          if (buf.substr(0, 3) != 'hxr')
              throw buf.length < 50 ? buf : 'Invalid hxr';
          var unpacker = new Unserializer(buf.substr(3));
          var data: {versions: Array<{name: String}>} = unpacker.unserialize();

ianharrigan · July 8, 2021, 8:36am

Yeah, nice one… now i have it working using remoting, i can get payloads etc and have managed to replicate a request in postman that seems to work fine… So as you point out, it would be fairly trivial i think to have it working with just raw http and get rid of the macros + hx3compat lib… thanks for the info, ill certainly likely use yours a starting point if / when i decide to go down that route.

Cheers,
Ian